CMakeToolchain：使用包内的 xxx-config.cmake 文件¶

在一般情况下，Conan 依赖于 package_info() 抽象来允许用任何构建系统构建的包可以被用任何其他构建系统构建的任何其他包使用。在 CMake 的情况下，Conan 依赖于 CMakeDeps 生成器为每个依赖项生成 xxxx-config.cmake 文件，即使这些依赖项没有生成一个文件或者根本不是用 CMake 构建的。

ConanCenter 用户这种抽象，不打包 xxx-config.cmake 文件，而是使用 package_info() 中的信息。这对于提供尽可能与构建系统无关的包，并公平对待不同的构建系统、供应商和用户非常重要。例如，有许多 Conan 用户很高兴地使用原生的 MSBuild (VS) 项目，根本没有使用任何 CMake。如果 ConanCenter 包仅使用包内的 config.cmake 文件构建，这将是不可能的。

但是，ConanCenter 这样做的事实并不意味着这是不可能的或强制性的。完全可以使用包内的 xxx-config.cmake 文件，而放弃使用 CMakeDeps 生成器。

你可以在 GitHub 上的 examples2 仓库中找到重新创建此示例的源代码。

$ git clone https://github.com/conan-io/examples2.git
$ cd examples2/examples/tools/cmake/pkg_config_files

如果我们看一下 conanfile.py

class pkgRecipe(ConanFile):
    name = "pkg"
    version = "0.1"
    ...

    def package_info(self):
        # No information provided, only the in-package .cmake is used here
        # Other build systems or CMake via CMakeDeps will fail
        self.cpp_info.builddirs = ["pkg/cmake"]
        self.cpp_info.set_property("cmake_find_mode", "none")

这是一个非常典型的配方，主要区别在于 package_info() 方法。需要注意三件重要的事情

它不定义像 self.cpp_info.libs = ["mypkg"] 这样的字段。Conan 不会将此信息传播给使用者，此信息的唯一位置将是在包内的 xxx-config.cmake 文件中。
以防万一仍有一些用户实例化 CMakeDeps，它使用 set_property("cmake_find_mode", "none") 禁用客户端生成 xxx-config.cmake 文件。
它定义它将在该文件夹内包含构建脚本（如 xxx-config.cmake 包），以便消费者可以找到。

因此，定义包详细信息的责任已转移到包含以下内容的 CMakeLists.txt。

add_library(mylib src/pkg.cpp)  # Use a different name than the package, to make sure

set_target_properties(mylib PROPERTIES PUBLIC_HEADER "include/pkg.h")
target_include_directories(mylib PUBLIC
        $<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>
        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
    )

# Use non default mypkgConfig name
install(TARGETS mylib EXPORT mypkgConfig)
export(TARGETS mylib
    NAMESPACE mypkg::  # to simulate a different name and see it works
    FILE "${CMAKE_CURRENT_BINARY_DIR}/mypkgConfig.cmake"
)
install(EXPORT mypkgConfig
    DESTINATION "${CMAKE_INSTALL_PREFIX}/pkg/cmake"
    NAMESPACE mypkg::
)

有了这些信息，当执行 conan create 时

build() 方法将构建包
package() 方法将调用 cmake install，这将创建 mypkgConfig.cmake 文件
它将在包文件夹 pkg/cmake/mypkgConfig.cmake 文件中创建
它将包含足够的信息用于头文件，并且将创建一个 mypkg::mylib 目标。

请注意，配置文件名、命名空间和目标的详细信息也是 Conan 所不知道的，因此这也是消费者构建脚本应该知道的事情。

这足以拥有一个包含内部 mypkgConfig.cmake 文件的包，该文件可以被消费者使用。在此示例代码中，使用者只是 test_package/conanfile.py，但完全相同的方法适用于任何任意的使用者。

消费者 conanfile.py 根本不需要使用 CMakeDeps，只需要使用 generators = "CMakeToolchain"。请注意，仍然需要 CMakeToolchain 生成器，因为需要在 Conan 缓存中找到 mypkgConfig.cmake。CMakeToolchain 生成的 conan_toolchain.cmake 文件包含定义的这些路径。

消费者 CMakeLists.txt 将是标准的

find_package(mypkg CONFIG REQUIRED)

add_executable(example src/example.cpp)
target_link_libraries(example mypkg::mylib)

你可以通过以下方式验证它是否有效

$ conan create .

======== Testing the package: Executing test ========
pkg/0.1 (test package): Running test()
pkg/0.1 (test package): RUN: Release\example
pkg/0.1: Hello World Release!
pkg/0.1: _M_X64 defined
pkg/0.1: MSVC runtime: MultiThreadedDLL
pkg/0.1: _MSC_VER1939
pkg/0.1: _MSVC_LANG201402
pkg/0.1: __cplusplus199711
pkg/0.1 test_package

重要注意事项¶

所提出的方法有一个限制，它不适用于多配置 IDE。实现这种方法将不允许开发人员直接从 Visual Studio 等 IDE 中从 Release 切换到 Debug，反之亦然，并且需要 conan install 进行更改。对于单配置设置来说，这根本不是问题，但对于 VS 开发人员来说，这可能会有点不方便。该团队正在开发可能有助于缓解此问题的 VS 插件。原因是 CMake 的一个限制，find_package() 只能找到一个配置，并且此处删除 CMakeDeps 后，Conan 无法避免此限制。

重要的是要知道，包作者和包 CMakeLists.txt 也有责任正确管理对其他依赖项的传递性，而在某些情况下，这并非易事。如果操作不正确，则存在包内的 xxx-config.cmake 文件可能会将传递依赖项定位到其他位置（例如在系统中），而不是在传递的 Conan 包依赖项中的风险。

最后，请记住，这些包将无法被 CMake 以外的其他构建系统使用。